#!/usr/bin/perl
# getmsmp3 v0.1 - download myspace mp3s
# Copyright (C) 2007 Peter Willis <peterwwillis@yahoo.com>

print <<EOF;
Since this program can only download publically-accessible files with no
authentication it is assumed all file downloads are legal until MySpace
decides to implement some DRM or at least a username and password requirement.
Or heck, even a "please-dont-download-MP3s" click-through license.
In the meanwhile you the user assume all liability by using this program.
I the author provide no warranty expressed or implied about anything.
Use this program at your own risk. You have been warned.

Pass this program the URL to a myspace page with a myspace mp3 player or
myspace playlist and it will save each MP3 it can find to the current
directory in a "bandname - songname.mp3" format.

EOF

use strict;
use LWP::Simple qw(get head getprint getstore is_success is_error);
use MIME::Base64 qw(encode_base64 decode_base64);
use XML::Simple qw(XMLin XMLout);

if ( ! @ARGV ) {
	die "Usage: $0 MYSPACE_URL ..\n" .
	 "  Downloads both profile songs and band playlists\n";
}

foreach my $PAGE (@ARGV) {
	my @IDS;
	my $content = get($PAGE);
	my @_IDS = find_mp3s(\$content);
	foreach my $id (@_IDS) {
		if ( $id !~ /\^/ ) { # band id
			push(@IDS, get_band_playlist($id));
		} else { # song id
			push(@IDS, $id);
		}
	}
	foreach my $id (@IDS) {
		save_mp3($id);
	}
}

exit(0);

sub get_band_playlist {
	my $id = shift;
	my $XMLstring = get("http://mediaservices.myspace.com/services/media/musicplayerxml.ashx?b=$id") || die "Error: couldn't get XML: $!\n";
	my $h = XMLin($XMLstring);
	my %IDS;
	foreach my $s_hr ( @{ $h->{playlist}->{song} } ) {
		my $_id = "$id^$s_hr->{bsid}";
		if ( !exists $IDS{$_id} ) {
			$IDS{$_id} = 1;
		}
	}
	return(keys %IDS);
}

sub find_mp3s {
	my $content_r = shift;
	my %IDS;
	while ( $$content_r =~ /\"(http:\/\/lads\.myspace\.com\/[^"]+?)"/img ) {
		my $url = $1;
		# band playlist
		if ( $url =~ /\/music\/musicplayer\.swf.+&d=([^&]+?)$/i ) {
			my $id = (split(/\^/, decode_base64($1)))[0];
			if ( !exists $IDS{$id} ) {
				$IDS{$id} = 1;
			}
		} elsif ( $url =~ /\/mini\/mini\.swf\?b=([^&]+)&o=([^&]+)/ig ) {
			my $id = join("^", (decode_base64($2),decode_base64($1)));
			if ( !exists $IDS{$id} ) {
				$IDS{$id} = 1;
			}
		}
	}
	return(keys %IDS);
}

# takes "o=" and "b=" base64-encoded form elements as arguments
# optionally a file name to save to, or "guesses"
sub save_mp3 {
	#my ($O, $B) = ( decode_base64($_[0]), decode_base64($_[1]) );
	my ($O, $B) = split(/\^/, $_[0]);
	my $XMLstring = get("http://mediaservices.myspace.com/services/media/musicplayerxml.ashx?b=$O&s=$B") || die "Error: could not retrieve XML ($!)\n";
	my $h = XMLin($XMLstring);
	if ( $h->{curl} !~ /&p=(.+)$/ ) {
		die "Bad p ($h->{curl})\n";
	}
	my $newurl = "$h->{durl}?bandid=$O&songid=$B&token=$h->{token}&p=$1&a=1";
	my @file;
	foreach my $crap ($h->{bandname}, $h->{songname}) {
		push(@file, $crap) if (defined $crap and length $crap > 0);
	}
	my $file = ( join(" - ", @file) || "$O-$B" ) . ".mp3";
	print "Saving \"$file\"\n";
	getstore($newurl,$file) || die "Error: could not get MP3 and store in \"$file\": $!\n";
}